plomlompom.com Git - plomvi.el/blob - plomvi.el

   1 ;;; plomvi.el --- poor man's vim emulation
   2
   3 ;; Copyright (C) 2019
   4
   5 ;; Author: Christian Heller <plom+plomvi@plomlompom.com>
   6
   7 ;; This program is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11
  12 ;; This program is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 ;;; Commentary:
  21
  22 ;; A very imperfect simulation of a small subset of Vim behavior, far
  23 ;; from the sophistication of packages like evil; an intentionally
  24 ;; thin wrapper around native Emacs behavior instead. To the author,
  25 ;; it mostly serves to both avoid muscle memory context switches
  26 ;; between Emacs and most basic Vim usages, and at the same time avoid
  27 ;; the conceptual distances evil puts between the user and native
  28 ;; Emacs logic. It does not care though to keep default Emacs
  29 ;; keybindings intact, overwriting some common ones with those from
  30 ;; the Vim universe.
  31
  32 ;;; Instructions:
  33
  34 ;; 1. load this script at the end of your init file: (load ...)
  35
  36 ;; 2. to start plomvi by default, put this right after:
  37 ;; (plomvi-global-mode 1)
  38
  39 ;; 3. if you want to use a different keybinding than "C-c C-c C-c"
  40 ;; to simulate the jump back from Insert to Normal mode in Vim (de
  41 ;; facto just a plomvi mode activation), put a line such as this
  42 ;; before the (load ...) line for plomvi (with "C-c" the desired
  43 ;; combo):
  44 ;; (defvar plomvi-return-combo (kbd "C-c"))
  45
  46
  47
  48 (defun plomvi-half-scroll()
  49   "Scroll down half a screen width."
  50   (interactive)
  51   (scroll-up (/ (window-height) 2)))
  52
  53 (defun plomvi-goto-line (count)
  54   "Jump to line: on nil count, last one, else count."
  55   (interactive "P")
  56   (if (null count)
  57       (goto-char (point-max))
  58     (goto-char (point-min))
  59     (forward-line (1- count))))
  60
  61 (defun plomvi-prefix-zero-or-line-start (prev-prefix)
  62   "If no prefix so far, jump to start of line, else start new prefix with 0."
  63   (interactive "P")
  64   (if (null prev-prefix)
  65       (beginning-of-line)
  66     (setq prefix-arg 0)))
  67
  68 (defun plomvi-prompt (prompt-input)
  69   "Provide super-basic : prompt that only accepts:
  70 q
  71 q!
  72 w
  73 w FILENAME
  74 wq
  75 vsplit
  76 split
  77
  78 If search and replace syntax is detected, it recommends using `query-replace'
  79 instead.
  80 "
  81   (interactive "M:")
  82   (cond
  83    ((string= prompt-input "q!")
  84     (kill-emacs))
  85    ((string= prompt-input "q")
  86     (save-buffers-kill-emacs))
  87    ((string= prompt-input "w")
  88     (save-buffer))
  89    ((string-match "^w [^ ]+" prompt-input)
  90     (let ((file-name (substring prompt-input 2))) (write-file file-name)))
  91    ((string-match "^%?s/" prompt-input)
  92     (message "NOT IMPLEMENTED, consider using query-replace(-regexp)"))
  93    ((string= prompt-input "wq")
  94     ((lambda () (save-some-buffers t) (kill-emacs))))
  95    ((string= prompt-input "vsplit")
  96     (split-window-horizontally))
  97    ((string= prompt-input "split")
  98     (split-window-vertically))
  99    (t (message "NOT IMPLEMENTED"))))
 100
 101 (defun plomvi-newline-above ()
 102   "Open and jump into new line above current line, deactivate `plomvi-mode'."
 103   (interactive)
 104   (beginning-of-line)
 105   (insert "\n")
 106   (previous-line)
 107   (plomvi-deactivate))
 108
 109 (defun plomvi-newline-below ()
 110   "Open and jump into new line below current line, deactivate `plomvi-mode'."
 111   (interactive)
 112   (end-of-line)
 113   (insert "\n")
 114   (plomvi-deactivate))
 115
 116 (defun plomvi-paste-backward ()
 117   "Paste last kill leftwards in current line, or (if kill ends in \n) above it.
 118
 119 Note that this ignores killed rectangles.
 120 "
 121   (interactive)
 122   (if (eq nil (string-match "\n$" (current-kill 0)))
 123       (yank)
 124     (beginning-of-line)
 125     (yank)
 126     (previous-line)))
 127
 128 (defun plomvi-paste-forward ()
 129   "Paste last kill rightwards in current line, or (if kill ends in \n) under it.
 130
 131 Note that this ignores killed rectangles."
 132   (interactive)
 133   (if (eq nil (string-match "\n$" (current-kill 0)))
 134       (progn
 135         (right-char)
 136         (yank))
 137     (end-of-line)
 138     (right-char)
 139     (yank)
 140     (previous-line)))
 141
 142 (defun plomvi-affect-lines-of-region(f)
 143   "Call f on start of first line of region and end of last line of region."
 144   (let* ((start-start-pos (region-beginning))
 145          (start-end-pos (region-end))
 146          (region-start (progn
 147                          (goto-char start-start-pos)
 148                          (line-beginning-position)))
 149          (region-end (progn
 150                        (goto-char start-end-pos)
 151                        (+ 1 (line-end-position)))))
 152     (funcall f region-start region-end)
 153     (goto-char region-start)))
 154
 155 (defun plomvi-kill-region-lines()
 156   "Kill lines of marked region."
 157   (interactive)
 158   (plomvi-affect-lines-of-region 'kill-region))
 159
 160 (defun plomvi-x()
 161   "If rectangle or region marked, kill those; else, kill char after point."
 162   (interactive)
 163   (cond
 164    ((and (boundp 'rectangle-mark-mode) (eq t rectangle-mark-mode))
 165     (kill-rectangle (region-beginning) (region-end)))
 166    ((use-region-p)
 167     (kill-region (region-beginning) (region-end)))
 168    ((not (= (point) (line-end-position)))
 169     (delete-char 1))
 170    ((not (= (line-beginning-position) (line-end-position)))
 171     (backward-char) (delete-char 1))))
 172
 173 (defun plomvi-rectangle-mark()
 174   "Start marked rectangle, move right one char so a single column is visible."
 175   (interactive)
 176   (push-mark (point) nil t)
 177   (rectangle-mark-mode)
 178   (right-char))
 179
 180 (defun plomvi-search-forward()
 181   "Find next occurence of search string last targeted by isearch."
 182   (interactive)
 183   (search-forward isearch-string))
 184
 185 (defun plomvi-search-backward()
 186   "Find previous  occurence of search string last targeted by isearch."
 187   (interactive)
 188   (search-backward isearch-string))
 189
 190 (defun plomvi-Y()
 191   "Copy rectangle, or full line, or region in full lines."
 192   (interactive)
 193   (cond
 194    ((and (boundp 'rectangle-mark-mode) (eq t rectangle-mark-mode))
 195     (copy-rectangle-as-kill (region-beginning) (region-end)))
 196    ((use-region-p)
 197     (plomvi-affect-lines-of-region 'copy-region-as-kill))
 198    (t
 199     (copy-region-as-kill (line-beginning-position) (+ 1 (line-end-position))))))
 200
 201 (defun plomvi-copy-region()
 202   "Copy marked region."
 203   (interactive)
 204   (copy-region-as-kill (region-beginning) (region-end)))
 205
 206 (defun plomvi-replace-char (c)
 207   "Replace char after point with c."
 208   (interactive "cplomvi-replace-char")
 209   (delete-char 1) (insert-char c) (left-char))
 210
 211 (defun plomvi-no-redo()
 212   "Tell user what to do, since implementing vim redo was too much of a hassle."
 213   (interactive)
 214   (message "Vim-style redo not available. Try M-x for Emacs' undo-undo."))
 215
 216 (defun plomvi-activate()
 217   "Activate `plomvi-mode'."
 218   (interactive)
 219   (plomvi-mode))
 220
 221 (defun plomvi-deactivate()
 222   "Deactivate `plomvi-mode'."
 223   (interactive)
 224   (plomvi-mode -1))
 225
 226 (defvar plomvi-mode-basic-map (make-sparse-keymap)
 227   "Keymap for `plomvi-mode' on read-only buffers.
 228
 229 In contrast to the keymap `plomvi-editable-mode' for editable
 230 buffers, this excludes keybindings for editing text, which thus
 231 become available to be used for other purposes.")
 232 (suppress-keymap plomvi-mode-basic-map t)
 233 (define-key plomvi-mode-basic-map (kbd ":") 'plomvi-prompt)
 234 (define-key plomvi-mode-basic-map (kbd "C-w") 'other-window)
 235 (define-key plomvi-mode-basic-map (kbd "k") 'previous-line)
 236 (define-key plomvi-mode-basic-map (kbd "j") 'next-line)
 237 (define-key plomvi-mode-basic-map (kbd "h") 'left-char)
 238 (define-key plomvi-mode-basic-map (kbd "l") 'right-char)
 239 (define-key plomvi-mode-basic-map (kbd "w") 'forward-word)
 240 (define-key plomvi-mode-basic-map (kbd "b") 'backward-word)
 241 (define-key plomvi-mode-basic-map (kbd "/") 'isearch-forward)
 242 (define-key plomvi-mode-basic-map (kbd "N") 'plomvi-search-backward)
 243 (define-key plomvi-mode-basic-map (kbd "n") 'plomvi-search-forward)
 244 (define-key plomvi-mode-basic-map (kbd "v") 'set-mark-command)
 245 (define-key plomvi-mode-basic-map (kbd "C-v") 'plomvi-rectangle-mark)
 246 (define-prefix-command 'plomvi-g-map)
 247 (define-key plomvi-mode-basic-map (kbd "g") 'plomvi-g-map)
 248 (define-key plomvi-g-map (kbd "g") 'beginning-of-buffer)
 249 (define-key plomvi-mode-basic-map (kbd "G") 'plomvi-goto-line)
 250 (define-key plomvi-mode-basic-map (kbd "$") 'end-of-line)
 251 (define-key plomvi-mode-basic-map (kbd "0") 'plomvi-prefix-zero-or-line-start)
 252 (define-key plomvi-mode-basic-map (kbd "1") 'digit-argument)
 253 (define-key plomvi-mode-basic-map (kbd "2") 'digit-argument)
 254 (define-key plomvi-mode-basic-map (kbd "3") 'digit-argument)
 255 (define-key plomvi-mode-basic-map (kbd "4") 'digit-argument)
 256 (define-key plomvi-mode-basic-map (kbd "5") 'digit-argument)
 257 (define-key plomvi-mode-basic-map (kbd "6") 'digit-argument)
 258 (define-key plomvi-mode-basic-map (kbd "7") 'digit-argument)
 259 (define-key plomvi-mode-basic-map (kbd "8") 'digit-argument)
 260 (define-key plomvi-mode-basic-map (kbd "9") 'digit-argument)
 261 (define-key plomvi-mode-basic-map (kbd "C-b") 'scroll-down)
 262 (define-key plomvi-mode-basic-map (kbd "C-f") 'scroll-up)
 263 (define-key plomvi-mode-basic-map (kbd "C-d") 'plomvi-half-scroll)
 264
 265 (defvar plomvi-mode-editable-map (make-sparse-keymap)
 266   "Keymap for `plomvi-mode' on editable buffers.
 267
 268 Inherits from `plomvi-mode-basic-map', but adds keybindings for
 269 text editing.")
 270 (set-keymap-parent plomvi-mode-editable-map plomvi-mode-basic-map)
 271 (define-key plomvi-mode-editable-map (kbd "i") 'plomvi-deactivate)
 272 (define-key plomvi-mode-editable-map (kbd "x") 'plomvi-x)
 273 (define-key plomvi-mode-editable-map (kbd "o") 'plomvi-newline-below)
 274 (define-key plomvi-mode-editable-map (kbd "O") 'plomvi-newline-above)
 275 (define-key plomvi-mode-editable-map (kbd "r") 'plomvi-replace-char)
 276 (define-key plomvi-mode-editable-map (kbd "u") 'undo-only)
 277 (define-key plomvi-mode-editable-map (kbd "C-r") 'plomvi-no-redo)
 278 (define-key plomvi-mode-editable-map (kbd "I") 'string-insert-rectangle)
 279 (define-key plomvi-mode-editable-map (kbd "p") 'plomvi-paste-forward)
 280 (define-key plomvi-mode-editable-map (kbd "P") 'plomvi-paste-backward)
 281 (define-key plomvi-mode-editable-map (kbd "Y") 'plomvi-Y)
 282 (define-key plomvi-mode-editable-map (kbd "y") 'plomvi-copy-region)
 283 (define-key plomvi-mode-editable-map (kbd "D") 'plomvi-kill-region-lines)
 284 (define-prefix-command 'plomvi-d-map)
 285 (define-key plomvi-mode-editable-map (kbd "d") 'plomvi-d-map)
 286 (define-key plomvi-d-map (kbd "w") 'kill-word)
 287 (define-key plomvi-d-map (kbd "$") 'kill-line)
 288 (define-key plomvi-d-map (kbd "d") 'kill-whole-line)
 289 (defvar plomvi-mode-hook)
 290 (defvar plomvi-mode-basic-hook)
 291 (defvar plomvi-mode-editable-hook)
 292 (defvar plomvi-mode-disable-hook)
 293 (defvar plomvi-mode-basic-disable-hook)
 294 (defvar plomvi-mode-editable-disable-hook)
 295 (defvar-local plomvi-mode nil "mode variable for `plomvi-mode'")
 296 (defvar-local plomvi-mode-basic nil
 297   "toggles `plomvi-mode-basic-map' in `minor-mode-map-alist' for `plomvi-mode'")
 298 (defvar-local plomvi-mode-editable nil
 299   "toggles `plomvi-mode-editable-map' in `minor-mode-map-alist' for `plomvi-mode'")
 300
 301 (defun plomvi-mode (&optional arg)
 302   "Imperfectly emulates a subset of Vim's Normal mode.
 303
 304 Sets mode variable `plomvi-mode' and, on read-only buffers, `plomvi-mode-basic',
 305 or, on editable buffers, `plomvi-mode-editable'. The latter two's values in
 306 `minor-mode-map-alist' toggle either `plomvi-mode-basic-map' or
 307 `plomvi-mode-editable-map'."
 308   (interactive (list (or current-prefix-arg 'toggle)))
 309   (let ((enable (if (eq arg 'toggle)                   ; follow suggestions
 310                     (not plomvi-mode)                  ; from (elisp)Minor
 311                   (> (prefix-numeric-value arg) 0 )))) ; Mode Conventions
 312     (if enable
 313         (unless (minibufferp)
 314           (if buffer-read-only
 315               (setq plomvi-mode-basic t)
 316             (setq plomvi-mode-editable t))
 317           (setq plomvi-mode t)
 318           (run-hooks 'plomvi-mode-hook)
 319           (if plomvi-mode-basic
 320               (run-hooks 'plomvi-mode-basic-hook)
 321             (run-hooks 'plomvi-mode-editable-hook)))
 322       (setq plomvi-mode-editable nil
 323             plomvi-mode-basic nil
 324             plomvi-mode nil)
 325       (run-hooks 'plomvi-mode-editable-disable-hook)
 326       (run-hooks 'plomvi-mode-basic-disable-hook)
 327       (run-hooks 'plomvi-mode-disable-hook))))
 328
 329 (define-globalized-minor-mode plomvi-global-mode plomvi-mode plomvi-activate)
 330 (add-to-list 'minor-mode-alist '(plomvi-mode " PV"))
 331 (add-to-list 'minor-mode-map-alist (cons 'plomvi-mode-basic
 332                                          plomvi-mode-basic-map))
 333 (add-to-list 'minor-mode-map-alist (cons 'plomvi-mode-editable
 334                                          plomvi-mode-editable-map))
 335
 336 (defvar plomvi-callable-mode-map
 337   (let ((map (make-sparse-keymap))
 338         (return-combo (if (boundp 'plomvi-return-combo)
 339                           plomvi-return-combo
 340                         (kbd "C-c C-c C-c"))))
 341     (define-key map return-combo 'plomvi-activate)
 342     map))
 343 (define-minor-mode plomvi-callable-mode ""
 344   :init-value t :keymap "plomvi-callable")