plomlompom.com Git - plomvi.el/blob - plomvi.el

   1 ;;; plomvi.el --- poor man's vim emulation
   2
   3 ;; Copyright (C) 2019
   4
   5 ;; Author: Christian Heller <plom+plomvi@plomlompom.com>
   6
   7 ;; This program is free software; you can redistribute it and/or modify
   8 ;; it under the terms of the GNU General Public License as published by
   9 ;; the Free Software Foundation, either version 3 of the License, or
  10 ;; (at your option) any later version.
  11
  12 ;; This program is distributed in the hope that it will be useful,
  13 ;; but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 ;; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 ;; GNU General Public License for more details.
  16
  17 ;; You should have received a copy of the GNU General Public License
  18 ;; along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19
  20 ;;; Commentary:
  21
  22 ;; A very imperfect simulation of a small subset of Vim behavior, far
  23 ;; from the sophistication of packages like evil; an intentionally
  24 ;; thin wrapper around native Emacs behavior instead. To the author,
  25 ;; it mostly serves to both avoid muscle memory context switches
  26 ;; between Emacs and most basic Vim usages, and at the same time avoid
  27 ;; the conceptual distances evil puts between the user and native
  28 ;; Emacs logic. It does not care though to keep default Emacs
  29 ;; keybindings intact, overwriting some common ones with those from
  30 ;; the Vim universe.
  31
  32 ;;; Instructions:
  33
  34 ;; 1. load this script into your init file: (load ...)
  35
  36 ;; 2. to start plomvi by default, put this into your init file:
  37 ;; (plomvi-global-mode 1)
  38
  39 ;; 3. define some otherwise unused keybinding to simulate what would
  40 ;; be a jump back from Insert mode to Normal mode in Vim (but is de
  41 ;; facto just a plomvi mode activation), such as this:
  42 ;; (global-set-key (kbd "<f1>") 'plomvi-activate)
  43
  44
  45
  46 (defun plomvi-nothing()
  47   "Do nothing. Used to shadow self-insert bindings in `plomvi-mode-editable-map'."
  48   (interactive))
  49
  50 (defun plomvi-half-scroll()
  51   "Scroll down half a screen width."
  52   (interactive)
  53   (scroll-up (/ (window-height) 2)))
  54
  55 (defun plomvi-goto-line (count)
  56   "Jump to line: on nil count, last one, else count."
  57   (interactive "P")
  58   (if (null count)
  59       (goto-char (point-max))
  60     (goto-char (point-min))
  61     (forward-line (1- count))))
  62
  63 (defun plomvi-prefix-zero-or-line-start (prev-prefix)
  64   "If no prefix so far, jump to start of line, else start new prefix with 0."
  65   (interactive "P")
  66   (if (null prev-prefix)
  67       (beginning-of-line)
  68     (setq prefix-arg 0)))
  69
  70 (defun plomvi-prompt (prompt-input)
  71   "Provide super-basic : prompt that only accepts:
  72 q
  73 q!
  74 w
  75 w FILENAME
  76 wq
  77 vsplit
  78 split
  79
  80 If search and replace syntax is detected, it recommends using `query-replace'
  81 instead.
  82 "
  83   (interactive "M:")
  84   (cond
  85    ((string= prompt-input "q!")
  86     (kill-emacs))
  87    ((string= prompt-input "q")
  88     (save-buffers-kill-emacs))
  89    ((string= prompt-input "w")
  90     (save-buffer))
  91    ((string-match "^w [^ ]+" prompt-input)
  92     (let ((file-name (substring prompt-input 2))) (write-file file-name)))
  93    ((string-match "^%?s/" prompt-input)
  94     (message "NOT IMPLEMENTED, consider using query-replace(-regexp)"))
  95    ((string= prompt-input "wq")
  96     ((lambda () (save-some-buffers t) (kill-emacs))))
  97    ((string= prompt-input "vsplit")
  98     (split-window-horizontally))
  99    ((string= prompt-input "split")
 100     (split-window-vertically))
 101    (t (message "NOT IMPLEMENTED"))))
 102
 103 (defun plomvi-newline-above ()
 104   "Open and jump into new line above current line, deactivate `plomvi-mode'."
 105   (interactive)
 106   (beginning-of-line)
 107   (insert "\n")
 108   (previous-line)
 109   (plomvi-deactivate))
 110
 111 (defun plomvi-newline-below ()
 112   "Open and jump into new line below current line, deactivate `plomvi-mode'."
 113   (interactive)
 114   (end-of-line)
 115   (insert "\n")
 116   (plomvi-deactivate))
 117
 118 (defun plomvi-paste-backward ()
 119   "Paste last kill leftwards in current line, or (if kill ends in \n) above it.
 120
 121 Note that this ignores killed rectangles.
 122 "
 123   (interactive)
 124   (if (eq nil (string-match "\n$" (current-kill 0)))
 125       (yank)
 126     (beginning-of-line)
 127     (yank)
 128     (previous-line)))
 129
 130 (defun plomvi-paste-forward ()
 131   "Paste last kill rightwards in current line, or (if kill ends in \n) under it.
 132
 133 Note that this ignores killed rectangles."
 134   (interactive)
 135   (if (eq nil (string-match "\n$" (current-kill 0)))
 136       (progn
 137         (right-char)
 138         (yank))
 139     (end-of-line)
 140     (right-char)
 141     (yank)
 142     (previous-line)))
 143
 144 (defun plomvi-region-kill()
 145   "Kill marked region."
 146   (interactive)
 147   (kill-region (region-beginning) (region-end)))
 148
 149 (defun plomvi-x()
 150   "If rectangle or region marked, kill those; else, kill char after point."
 151   (interactive)
 152   (cond
 153    ((and (boundp 'rectangle-mark-mode) (eq t rectangle-mark-mode))
 154     (kill-rectangle (region-beginning) (region-end)))
 155    ((use-region-p)
 156     (plomvi-region-kill))
 157    (t
 158     (delete-char 1))))
 159
 160 (defun plomvi-rectangle-mark()
 161   "Start marked rectangle, move right one char so a single column is visible."
 162   (interactive)
 163   (push-mark (point) nil t)
 164   (rectangle-mark-mode)
 165   (right-char))
 166
 167 (defun plomvi-search-forward()
 168   "Find next occurence of search string last targeted by isearch."
 169   (interactive)
 170   (search-forward isearch-string))
 171
 172 (defun plomvi-search-backward()
 173   "Find previous  occurence of search string last targeted by isearch."
 174   (interactive)
 175   (search-backward isearch-string))
 176
 177
 178 (defun plomvi-copy-line()
 179   "Copy current line into kill buffer."
 180   (interactive)
 181   (let ((keep_pos (point)))  ; We sort of cheat: We kill the line, then we
 182     (kill-whole-line)        ; paste it back, and return point to its
 183     (plomvi-paste-backward)  ; original position.
 184     (goto-char keep_pos)))   ;
 185
 186 (defun plomvi-copy-region()
 187   "Copy marked region."
 188   (interactive)
 189   (copy-region-as-kill (region-beginning) (region-end)))
 190
 191 (defun plomvi-replace-char (c)
 192   "Replace char after point with c."
 193   (interactive "cplomvi-replace-char")
 194   (delete-char 1) (insert-char c) (left-char))
 195
 196 (defun plomvi-no-redo()
 197   "Tell user what to do, since implementing vim redo was too much of a hassle."
 198   (interactive)
 199   (message "Vim-style redo not available. Try M-x for Emacs' undo-undo."))
 200
 201 (defun plomvi-activate()
 202   "Activate `plomvi-mode'."
 203   (interactive)
 204   (plomvi-mode))
 205
 206 (defun plomvi-deactivate()
 207   "Deactivate `plomvi-mode'."
 208   (interactive)
 209   (plomvi-mode -1))
 210
 211 (defvar plomvi-mode-basic-map (make-sparse-keymap)
 212   "Keymap for `plomvi-mode' on read-only buffers.
 213
 214 In contrast to the keymap `plomvi-editable-mode' for editable buffers,
 215 this not only excludes keybindings for editing text, but also does not
 216 shadow keybindings that are bound to `self-insert-command'.
 217
 218 Thus, it on the whole shadows much fewer keybindings of other keymaps
 219 that can therefore be used for other purposes.")
 220 (define-key plomvi-mode-basic-map (kbd ":") 'plomvi-prompt)
 221 (define-key plomvi-mode-basic-map (kbd "C-w") 'other-window)
 222 (define-key plomvi-mode-basic-map (kbd "k") 'previous-line)
 223 (define-key plomvi-mode-basic-map (kbd "j") 'next-line)
 224 (define-key plomvi-mode-basic-map (kbd "h") 'left-char)
 225 (define-key plomvi-mode-basic-map (kbd "l") 'right-char)
 226 (define-key plomvi-mode-basic-map (kbd "w") 'forward-word)
 227 (define-key plomvi-mode-basic-map (kbd "b") 'backward-word)
 228 (define-key plomvi-mode-basic-map (kbd "/") 'isearch-forward)
 229 (define-key plomvi-mode-basic-map (kbd "N") 'plomvi-search-backward)
 230 (define-key plomvi-mode-basic-map (kbd "n") 'plomvi-search-forward)
 231 (define-key plomvi-mode-basic-map (kbd "v") 'set-mark-command)
 232 (define-key plomvi-mode-basic-map (kbd "C-v") 'plomvi-rectangle-mark)
 233 (define-prefix-command 'plomvi-g-map)
 234 (define-key plomvi-mode-basic-map (kbd "g") 'plomvi-g-map)
 235 (define-key plomvi-g-map (kbd "g") 'beginning-of-buffer)
 236 (define-key plomvi-mode-basic-map (kbd "G") 'plomvi-goto-line)
 237 (define-key plomvi-mode-basic-map (kbd "$") 'end-of-line)
 238 (define-key plomvi-mode-basic-map (kbd "0") 'plomvi-prefix-zero-or-line-start)
 239 (define-key plomvi-mode-basic-map (kbd "1") 'digit-argument)
 240 (define-key plomvi-mode-basic-map (kbd "2") 'digit-argument)
 241 (define-key plomvi-mode-basic-map (kbd "3") 'digit-argument)
 242 (define-key plomvi-mode-basic-map (kbd "4") 'digit-argument)
 243 (define-key plomvi-mode-basic-map (kbd "5") 'digit-argument)
 244 (define-key plomvi-mode-basic-map (kbd "6") 'digit-argument)
 245 (define-key plomvi-mode-basic-map (kbd "7") 'digit-argument)
 246 (define-key plomvi-mode-basic-map (kbd "8") 'digit-argument)
 247 (define-key plomvi-mode-basic-map (kbd "9") 'digit-argument)
 248 (define-key plomvi-mode-basic-map (kbd "C-b") 'scroll-down)
 249 (define-key plomvi-mode-basic-map (kbd "C-f") 'scroll-up)
 250 (define-key plomvi-mode-basic-map (kbd "C-d") 'plomvi-half-scroll)
 251
 252 (defvar plomvi-mode-editable-map (make-sparse-keymap)
 253   "Keymap for `plomvi-mode' on editable buffers.
 254
 255 Inherits from `plomvi-mode-basic-map', but adds keybindings for text editing
 256 and shadows keybindings bound to `self-insert-command' to avoid accidentally
 257 typing text outside of what would be Vim's Insert mode.")
 258 (set-keymap-parent plomvi-mode-editable-map plomvi-mode-basic-map)
 259 (define-key plomvi-mode-editable-map [remap self-insert-command] 'plomvi-nothing)
 260 (define-key plomvi-mode-editable-map (kbd "i") 'plomvi-deactivate)
 261 (define-key plomvi-mode-editable-map (kbd "x") 'plomvi-x)
 262 (define-key plomvi-mode-editable-map (kbd "o") 'plomvi-newline-below)
 263 (define-key plomvi-mode-editable-map (kbd "O") 'plomvi-newline-above)
 264 (define-key plomvi-mode-editable-map (kbd "r") 'plomvi-replace-char)
 265 (define-key plomvi-mode-editable-map (kbd "u") 'undo-only)
 266 (define-key plomvi-mode-editable-map (kbd "C-r") 'plomvi-no-redo)
 267 (define-key plomvi-mode-editable-map (kbd "I") 'string-insert-rectangle)
 268 (define-key plomvi-mode-editable-map (kbd "p") 'plomvi-paste-forward)
 269 (define-key plomvi-mode-editable-map (kbd "P") 'plomvi-paste-backward)
 270 (define-key plomvi-mode-editable-map (kbd "Y") 'plomvi-copy-line)
 271 (define-key plomvi-mode-editable-map (kbd "y") 'plomvi-copy-region)
 272 (define-key plomvi-mode-editable-map (kbd "D") 'plomvi-region-kill)
 273 (define-prefix-command 'plomvi-d-map)
 274 (define-key plomvi-mode-editable-map (kbd "d") 'plomvi-d-map)
 275 (define-key plomvi-d-map (kbd "w") 'kill-word)
 276 (define-key plomvi-d-map (kbd "$") 'kill-line)
 277 (define-key plomvi-d-map (kbd "d") 'kill-whole-line)
 278 (defvar plomvi-mode-hook)
 279 (defvar plomvi-mode-basic-hook)
 280 (defvar plomvi-mode-editable-hook)
 281 (defvar plomvi-mode-disable-hook)
 282 (defvar plomvi-mode-basic-disable-hook)
 283 (defvar plomvi-mode-editable-disable-hook)
 284 (defvar-local plomvi-mode nil "mode variable for `plomvi-mode'")
 285 (defvar-local plomvi-mode-basic nil
 286   "toggles `plomvi-mode-basic-map' in `minor-mode-map-alist' for `plomvi-mode'")
 287 (defvar-local plomvi-mode-editable nil
 288   "toggles `plomvi-mode-editable-map' in `minor-mode-map-alist' for `plomvi-mode'")
 289
 290 (defun plomvi-mode (&optional arg)
 291   "Imperfectly emulates a subset of Vim's Normal mode.
 292
 293 Sets mode variable `plomvi-mode' and, on read-only buffers, `plomvi-mode-basic',
 294 or, on editable buffers, `plomvi-mode-editable'. The latter two's values in
 295 `minor-mode-map-alist' toggle either `plomvi-mode-basic-map' or
 296 `plomvi-mode-editable-map'."
 297   (interactive (list (or current-prefix-arg 'toggle)))
 298   (let ((enable (if (eq arg 'toggle)                   ; follow suggestions
 299                     (not plomvi-mode)                  ; from (elisp)Minor
 300                   (> (prefix-numeric-value arg) 0 )))) ; Mode Conventions
 301     (if enable
 302         (unless (minibufferp)
 303           (if buffer-read-only
 304               (setq plomvi-mode-basic t)
 305             (setq plomvi-mode-editable t))
 306           (setq plomvi-mode t)
 307           (run-hooks 'plomvi-mode-hook)
 308           (if plomvi-mode-basic
 309               (run-hooks 'plomvi-mode-basic-hook)
 310             (run-hooks 'plomvi-mode-editable-hook)))
 311       (setq plomvi-mode-editable nil
 312             plomvi-mode-basic nil
 313             plomvi-mode nil)
 314       (run-hooks 'plomvi-mode-editable-disable-hook)
 315       (run-hooks 'plomvi-mode-basic-disable-hook)
 316       (run-hooks 'plomvi-mode-disable-hook))))
 317
 318 (define-globalized-minor-mode plomvi-global-mode plomvi-mode plomvi-activate)
 319 (add-to-list 'minor-mode-alist '(plomvi-mode " PV"))
 320 (add-to-list 'minor-mode-map-alist (cons 'plomvi-mode-basic
 321                                          plomvi-mode-basic-map))
 322 (add-to-list 'minor-mode-map-alist (cons 'plomvi-mode-editable
 323                                          plomvi-mode-editable-map))